Proxy Switch con un file batch

| | 0 Comments

In questo articolo vediamo un semplicissimo Proxy Switcher fatto in batch, che fa On/Off del proxy di Windows. Selezionate il seguente codice e incollatelo in un file di testo e cambiatene l’estensione da .txt a .bat:

@echo off
SETLOCAL
SET key="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
SET value="http=proxy-url:port;https=proxy-url:port;ftp=proxy-url:port;socks=proxy-url:port;"
SET bypass="*.google.com;*.fbcdn.net;*.googleapis.com;<local>"
FOR /f "tokens=2* skip=2" %%a IN ('reg query %key% /v ProxyEnable') DO (
 SET data=%%b
)
IF %data%==0x0 (
 REG add %key% /v ProxyServer /d %value% /t REG_SZ /f
 REG add %key% /v ProxyOverride /d %bypass% /t REG_SZ /f
 REG add %key% /v ProxyEnable /t REG_DWORD /d 1 /f
 ECHO "PROXY ABILITATO"
) ELSE (
 REG add %key% /v ProxyEnable /t REG_DWORD /d 0 /f
 ECHO "PROXY DISABILITATO"
)
CD %ProgramFiles%\"Internet Explorer"
@start iexplore -embedding
TIMEOUT /T 2
TASKKILL /F /IM iexplore.exe

I parametri da cambiare sono value e bypass:

  • value può essere anche un indirizzo ip con la porta, ad esempio 192.168.10.1:8080, inserendo solo questo valore senza specificarne il protocollo verrà applicato per tutti (http, https, ftp, socks);
  • bypass, è la lista di host da bypassare, molto utile ad esempio per cdn che usate spesso e per indirizzi locali (localhost, <local>).

Per chi usa Internet Explorer ( ma perchè ?!) può essere utile rimuovere l’ultima riga in modo da non chiudere le vostre finestre.

Tags: , , ,

Category: Programmazione

About the Author ()

Studio Ingegneria Informatica e Bio. all' Università Magna Graecia di Catanzaro, sono appassionato di informatica, e mi piace praticare la pesca nelle acque dolci.